Module Mnet

Architecture overview.

mnet organizes the network stack in layers:

• Ethernet: The lowest layer, handling MAC-level frame I/O via Ethernet. A background daemon reads frames from the network device and dispatches them to upper-layer handlers.
• IPv4 / IPv6: IPv4 and IPv6 handle addressing, routing, fragmentation/reassembly, and neighbor/route discovery (ARP for IPv4, NDPv6 for IPv6).
• TCP / UDP: TCP (backed by utcp) provides reliable streams with a socket-like API. UDP provides unreliable datagrams.

The stack function wires all these layers together and returns the handles needed to use TCP and UDP.

Mnet and random number generators.

This library requires the initialization of a random number generator using Mirage_crypto_rng. To do this, it is possible to initialize such a generator upstream using Mkernel in this way:

  module RNG = Mirage_crypto_rng.Fortuna

  let rng () = Mirage_crypto_rng_mkernel.initialize (module RNG)
  let rng = Mkernel.map rng Mkernel.[]

  let run _ =
    Mkernel.(run [ rng; Mnet.stack ~name:"service" cidr ])
    @@ fun rng (stack, _, _) ->
    let@ () = fun () -> Mnet.kill stack in
    let@ () = fun () -> Mirage_crypto_rng_mkernel.kill rng in
    ...

Lifecycle management.

The stack spawns several background daemons (Ethernet reader, ARP responder, NDPv6 daemon, TCP timer, etc.). The caller must call kill when the stack is no longer needed to terminate all these daemons. A typical pattern uses Fun.protect:

  let ( let@ ) finally fn = Fun.protect ~finally fn
  let@ () = fun () -> Mnet.kill stack in
  (* use the stack ... *)

Full example: echo server.

module RNG = Mirage_crypto_rng.Fortuna

let ( let@ ) finally fn = Fun.protect ~finally fn
let rng () = Mirage_crypto_rng_mkernel.initialize (module RNG)
let rng = Mkernel.map rng Mkernel.[]
let cidr = Ipaddr.V4.Prefix.of_string_exn "10.0.0.2/24"

let () =
  Mkernel.(run [ rng; Mnet.stack ~name:"service" cidr ])
  @@ fun rng (stack, tcp, _udp) () ->
  let@ () = fun () -> Mnet.kill stack in
  let@ () = fun () -> Mirage_crypto_rng_mkernel.kill rng in
  let listen = Mnet.TCP.listen tcp 9000 in
  let flow = Mnet.TCP.accept tcp listen in
  let buf = Bytes.create 4096 in
  let len = Mnet.TCP.read flow buf in
  Mnet.TCP.write flow (Bytes.sub_string buf 0 len);
  Mnet.TCP.close flow

Stack creation and management

  $ solo5-hvt --net:service=tap0 -- ...